Текстовые функции

Приложение Excel предлагает довольно широкий выбор функций, с помощью которых обрабатывается текст. Большинство из них можно найти в библиотеке функций или диалоговом окне Мастер функций (чтобы открыть его, выберите команду ФормулыБиблиотека функцийТекстовыеВставить функцию). В категории Текстовые содержится большая часть текстовых функций. Некоторые другие функции, которые тоже могут использоваться при работе с текстом, встречаются в других категориях. Например, функция ЕТЕКСТ находится в категории Проверка свойств и значений.

Область применения большинства текстовых функций не ограничивается только текстом. Другими словами, эти функции могут использоваться и в ячейках, содержащих числовые значения. Excel предоставляет прекрасную возможность обрабатывать числа как текст и, наоборот, текст – как числа.

В этом разделе приводятся примеры некоторых широко распространенных операций, которые можно выполнять с текстом. Возможно, вы захотите взять себе на вооружение некоторые из приведенных ниже примеров.

Проверка наличия текста в ячейке

Если возникла необходимость в определении типа данных, содержащихся в отдельной ячейке, вам потребуется соответствующая формула, позволяющая сделать это. К примеру, можно использовать функцию ЕТЕКСТ, чтобы вставить в ячейку результат только в том случае, если он является текстом.

Функция ЕТЕКСТ принимает один аргумент и возвращает значение ИСТИНА, если ячейка содержит текст, или значение ЛОЖЬ в противном случае. К примеру, следующая формула вернет значение ИСТИНА, если ячейка А1 содержит текст:

=ЕТЕКСТ(А1)

Функция ТИП также имеет один аргумент и возвращает значение, которое указывает тип данных, содержащихся в ячейке. Например, если ячейка А1 содержит текстовую информацию, формула, приведенная ниже, вернет значение 2 (кодовый номер текстового формата):

=ТИП(А1)

Функция ЕТЕКСТ считает текстом также числовое значение, перед которым расположен апостроф. Однако она не считает текстом число, отформатированное как текст (если текстовый формат применен после ввода числа в ячейку).

Работа с кодами символов

Каждому символу, который виден на экране компьютера, соответствует определенное кодовое число. Для работы в системе Windows приложение Excel использует стандартный набор символов ANSI, который содержит 255 символов, пронумерованных числами в диапазоне от 1 до 255.

На рисунке показана часть рабочего листа приложения Excel, на котором представлены символы ANSI. В этом примере использовался установленный по умолчанию шрифт Calibri (другие шрифты отображают символы немного иначе).

Для работы с кодами символов Excel предоставляет две специальные функции: КОДСИМВ и СИМВОЛ. Несмотря на то, что эти функции не столь популярны, как остальные, они пригодятся при совместном использовании с другими функциями.

Функции КОДСИМВ и СИМВОЛ работают только со строками в кодировке ANSI. Эти функции не будут выполняться для строк в двухбайтовой кодировке Unicode.

Функция КОДСИМВ

Функция КОДСИМВ, которая используется в приложении Excel, возвращает код символа, введенного в качестве аргумента функции. Например, формула, приведенная ниже, возвращает значение 192 – код русского символа А, введенного в верхнем регистре.

=КОДСИМВ(“А”)

В том случае, если аргумент функции КОДСИМВ содержит несколько символов, функция использует только первый символ. Например, следующая формула возвращает значение 196 – код символа Д:

=КОДСИМВ(“Дорога к Риму”)

Функция СИМВОЛ

По своей сути функция СИМВОЛ полностью противоположна функции КОДСИМВ. Ее аргументом является числовое значение в интервале от 1 до 255, а сама функция возвращает символ, соответствующий этому значению. Например, приведенная ниже формула возвращает русский символ А:

=СИМВОЛ(192)

Чтобы продемонстрировать разницу между функциями КОДСИМВ и СИМВОЛ, введите в ячейку следующую формулу:

=СИМВОЛ(КОДСИМВ(“А”))

Формула вернет символ А. Этот пример лишь иллюстрирует действие функций, вряд ли он будет полезен на практике. Сначала введенный символ преобразуется в соответствующее значение кода (192), после чего функция СИМВОЛ возвращает символ А, который соответствует данному значению.

Теперь предположим, что ячейка А1 содержит символ А (в верхнем регистре). Тогда следующая формула вернет символ а (в нижнем регистре):

=СИМВОЛ(КОДСИМВ(А1)+32)

В этой формуле используется тот факт, что в кодовой таблице символы расположены последовательно, в алфавитном порядке, при этом символы нижнего регистра расположены после символов верхнего (между прописными и строчными буквами находится несколько других символов). Каждая строчная буква русского (равно как и английского) алфавита размещена ровно на 32 позиции выше своего прописного собрата.

Как найти специальные символы

Excel предоставляет прекрасную возможность использовать диалоговое окно Символ, которое можно вызвать, выбрав команду ВставкаСимволыСимвол. Это диалоговое окно позволяет вставить в ячейку любые специальные символы (включая символы Unicode). Например, можно вставить в электронную таблицу смайлик (если вдруг возникнет такая необходимость). Для этого в Excel достаточно открыть диалоговое окно Символ и выбрать шрифт Wingdings. Затем просмотрите символы, найдите изображение рожицы и щелкните на кнопке Вставить. Обратите внимание, что этому символу соответствует код 74.

Проверка идентичности строк

Чтобы определить, содержат ли две ячейки идентичные записи, используйте простую логическую формулу. Например, ниже приведена формула, с помощью которой можно определить, содержит ли ячейка А1 то же значение, что и ячейка А2:

=А1=А2

Следует отметить, что Excel немного “небрежна” в операциях сравнения текста. Рассмотрим, например, ситуацию, когда ячейка А1 содержит слово Январь (первая буква прописная), а ячейка А2 – слово ЯНВАРЬ (все буквы прописные). Приведенная выше формула вернет значение ИСТИНА, несмотря на то, что эти две ячейки содержат разные текстовые значения. Иными словами, при сравнении не учитывается регистр символов.

Чаще всего не стоит беспокоиться по поводу регистра символов текста. Если же необходимо при сравнении учитывать регистр символов, можно использовать функцию СОВПАД. Приведенная ниже формула возвращает значение ИСТИНА только в том случае, если ячейки А1 и А2 содержат абсолютно идентичные записи.

=СОВПАД(А1;А2)

Следующая формула возвращает значение ЛОЖЬ, поскольку первая строка содержит в конце пробел:

=СОВПАД(“нуль ”;“нуль”)

Объединение нескольких ячеек

Excel использует знак & как оператор конкатенации (объединения строк). Конкатенация – это просто модный термин, указывающий, что результат объединяет содержимое нескольких ячеек. Например, если ячейка А1 содержит текст Tucson, а ячейка А2 – California, приведенная ниже формула возвратит текст TucsonCalifornia:

=A1&A2

Обратите внимание, что эти две строки объединены без промежуточного пробела. Для того чтобы добавить пробел между двумя строками и получить текст Tucson California, необходимо использовать следующую формулу:

=A1&“ ”&А2

Другой способ, который, может быть, даже лучше предыдущего, – использовать запятую и пробел, чтобы получить текст Tucson, California.

=A1&“, ”&A2

Еще один способ объединения строк состоит в применении функций СИМВОЛ с соответствующими аргументами. Обратите внимание, что в приведенном ниже примере использования функции СИМВОЛ в объединяемый текст вставляются запятая (44) и пробел (32).

=А1&СИМВОЛ(44)&СИМВОЛ(32)&А2

Если вы решили перенести текст на другую строку, то при его объединении в строке необходимо использовать функцию СИМВОЛ (10). После этого проверьте, применен ли к ячейке текстовый формат с переносом слов (команда ГлавнаяВыравниваниеПеренос текста). Пример объединения текста в ячейке А1 и текста в ячейке В2 с символом переноса между ними продемонстрирован в следующей формуле:

=А1&СИМВОЛ(10)&В1

Ниже приведен еще один пример использования функции СИМВОЛ. Следующая формула возвращает строку Stop, объединяя четыре символа, полученные с помощью функции СИМВОЛ:

=СИМВОЛ(83)&СИМВОЛ(116)&СИМВОЛ(111)&СИМВОЛ(112)

Рассмотрим еще один пример использования оператора конкатенации, В данном случае формула объединяет текст с результатом выражения, которое возвращает максимальное значение столбца С.

=“Максимальное значение в столбце С: ”&МАКС(С:С)

Имейте в виду, что в Excel есть также функция СЦЕПИТЬ, которая поддерживает до 255 аргументов. Эта функция объединяет свои аргументы в единую строку. Многие пользователи предпочитают применять именно ее, однако использование оператора конкатенации (&) значительно проще.

Отображение значений как текста

Функция ТЕКСТ в приложении Excel позволяет отобразить значение ячейки в определенном числовом формате. На первый взгляд может показаться, что эта функция имеет весьма сомнительное применение. Однако она поможет осуществить некоторые полезные действия, предназначенные для решения важных задач, что и будет продемонстрировано в настоящем разделе. На рисунке показан обычный рабочий лист Excel. Ниже приведена формула, используемая в этом рабочем листе в ячейке А5.

=“Чистая прибыль: ”&В3

По существу, эта формула объединяет текстовую строку с содержимым ячейки ВЗ и отображает полученный результат. Обратите внимание, что в А5 к содержимому ВЗ не был применен ни один специальный формат. Тем не менее при желании можно установить для нее денежный формат с использованием пробелов и символа валюты.

Имейте в виду, что, вопреки ожиданиям, применение числового формата ко всей ячейке, содержащей формулу, не даст никакого эффекта. Все дело в том, что используемая формула возвращает строку, а не числовое значение.

Применить формат к содержимому ячейки ВЗ в ячейке А5 можно с помощью функции ТЕКСТ. Для этого нужно ввести в А5 такую формулу:

=“Чистая прибыль: ”&ТЕКСТ(В3;“### ### ###,00”)

Эта формула будет отображать и текст, и само отформатированное числовое значение следующим образом:

Чистая прибыль: 104 616,52р.

Второй аргумент функции ТЕКСТ содержит стандартное определение числового формата, используемого в приложении Excel. В качестве этого аргумента можно ввести любое другое допустимое определение числового формата.

В предыдущем примере мы использовали простую ссылку на ячейку ВЗ. Но это не единственная возможность. Вместо ссылки на ячейку можно использовать любое выражение. Ниже приведен пример, в котором текст объединяется с числом, полученным путем вызова функции СРЗНАЧ.

=“Средний расход: ”&ТЕКСТ(СРЗНАЧ(А:А);“#,##0,00р.”)

Эта формула возвращает такую строку:

Средний расход: 7 794,57р.

Теперь мы рассмотрим другой пример, в котором используется функция СЕГОДНЯ, возвращающая текущую дату и время. Использование этой функции совместно с функцией ТЕКСТ позволяет отобразить на экране текущую дату и время, представленные в удобном для восприятия формате.

=“Отчет напечатан ”&ТЕКСТ(СЕГОДНЯ();“д ММММ, гггг в ч:мм АМ/РМ”)

Эта формула отображает следующую запись:

Отчет напечатан 22 Июль, 2001 в 3:23 РМ

Отображение денежных значений, отформатированных как текст

В Excel существует функция РУБЛЬ, с помощью которой содержащееся в ячейке число преобразуется в текст, представленный в денежном формате. Эта функция использует два аргумента: число, которое необходимо преобразовать, и количество знаков, отображаемых на экране после запятой. Как правило, функция РУБЛЬ использует обозначения денежной единицы, установленной в региональных настройках Windows.

В отдельных случаях функция РУБЛЬ может использоваться вместо функции ТЕКСТ. Однако намного эффективнее применение функции ТЕКСТ, которая является более гибкой, поскольку не ограничивает вас определенным числовым форматом.

Приведенная ниже формула возвращает такой текст: Итого: 1 287,37р. Второй аргумент функции РУБЛЬ определяет количество десятичных знаков после запятой.

=“Итого: ”&РУБЛЬ(1287,367;2)

Удаление пробелов и непечатных символов

Довольно часто данные, импортированные в рабочий лист Excel, содержат лишние пробелы и причудливые символы, унаследованные от импортируемого формата. В Excel есть две функции, помогающие избавиться от них.

• Функция СЖПРОБЕЛЫ удаляет из строки ведущие и замыкающие пробелы. Кроме того, внутренние последовательности пробелов она заменяет одним пробелом.
• Функция ПЕЧСИМВ удаляет из строки все непечатаемые символы, которые в импортированном формате были служебными символами.

Рассмотрим пример использования функции СЖПРОБЕЛЫ. Приведенная ниже формула возвращает строку “Чистый доход за квартал” без лишних пробелов.

=СЖПРОБЕЛЫ(“ Чистый доход за квартал ”)

Подсчет символов в строке

Функция ДЛСТР принимает только один аргумент и возвращает количество символов, содержащихся в ячейке. Возьмем, например, ячейку А1, содержащую строку Продажи в сентябре. Формула, приведенная ниже, вернет значение 18.

=ДЛСТР(А1)

Обратите внимание, что пробелы тоже считаются символами и включаются в результирующее значение. К примеру, если ячейка А1 содержит строку Продажи и приведенная выше формула вернет значение 8, значит, в начале или конце строки есть пробел.

Следующая формула укорачивает текст, который оказался слишком длинным. Если в ячейке А1 содержится более десяти символов, формула возвращает первые 9 символов, за которыми следует символ троеточия (в кодовой таблице ANSI этот символ имеет код 133). Если символов десять или меньше, возвращается вся строка.

=ЕСЛИ(ДЛСТР(А1)>10;ЛЕВСИМВ(А1;9)&СИМВОЛ(133);А1)

Повторяющиеся символы и строки

Функция ПОВТОР предназначена для того, чтобы повторить любую строку текста или символ (первый аргумент) заданное количество раз (второй аргумент). Например, следующая формула возвращает текст НаНаНа:

=ПОВТОР(“На”;3)

Эту функцию удобно использовать для создания горизонтального разделителя между ячейками. Например, приведенная ниже формула создает строку, состоящую из 20 волнистых линий (тильд), расположенных по длине строки:

=ПОВТОР(“~”;20)

Создание текстовой гистограммы

Одно из наиболее полезных направлений использования функции ПОВТОР – это создание простой гистограммы непосредственно на рабочем листе. В этом случае необходимость применения диаграмм полностью отпадает. Подобный способ графического отображения данных особенно эффективен, когда необходимо визуально отобразить сумму большого количества значений. Стандартная диаграмма Excel для подобных случаев может оказаться слишком громоздкой.

Средства условного форматирования позволяют создавать простые гистограммы непосредственно в ячейках.

Формулы, содержащиеся в ячейках столбцов Е и G, графически отображают ежемесячное изменение бюджета, выводя на экран ряд символов шрифта Wingdings. В этом примере мы использовали символ n, который в выбранном шрифте отображается как маленький квадрат. Формула, использующая функцию ПОВТОР, определяет количество символов, которое должно быть отображено на экране. Формулы для ячеек, формирующих диаграмму, имеют следующий вид.

ЕЗ: =ЕСЛИ(D3<0;ПОВТОР(“n”;-ОКРУГЛ(D3*100;0));“”)
F3: =А3
G3: =ЕСЛИ(D3>0;ПОВТОР(“n”;ОКРУГЛ(D3*100;0));“”)

Установите для ячеек ЕЗ и G3 шрифт Wingdings, а затем скопируйте формулы, содержащиеся в этих ячейках, вниз в ячейки столбцов, чтобы распределить данные. Выровняйте текст в столбце Е по правому краю, после чего примените любое другое форматирование ячеек. Имейте в виду, что в зависимости от величины числового диапазона данных может возникнуть необходимость изменить масштаб значений. Поэкспериментируйте с перемещением 100 значений в формулах. Выбранный ранее для диаграммы символ n можно заменить на любой другой.

Добавление к числу заданных символов

Вероятно, многие из вас уже не раз сталкивались с таким распространенным (особенно при печати чеков) методом защиты, как дополнение числовых значений справа звездочками. Приведенная ниже формула, наряду со значением, содержащимся в ячейке А1, отображает знаки звездочек, дополняя общее количество символов до 24. Таким образом, пустые позиции ячейки заполняются звездочками.

=(А1&ПОВТОР(“*”;24-ДЛСТР(А1)))

Используя следующую формулу, можно добавить звездочки к числу слева:

=ПОВТОР(“*”;24-ДЛСТР(A1))&А1

Представленная далее формула отображает звездочки, дополняющие число сразу с двух сторон. Она возвращает 24 символа в том случае, если число в ячейке А1 содержит четное количество символов, и 23 символа, если число содержит нечетное количество символов.

=ПОВТОР(“*”;12-ДЛСТР(А1)/2)&А1&ПОВТОР(“*”;12-ДЛСТР(А1)/2)

Приведенные выше формулы не столь совершенны, поскольку они могут отображать не все отформатированные числа. Ниже приведена усовершенствованная версия формулы, которая отображает значение, содержащееся в ячейке А1 (отформатированной ячейке), а также знаки звездочек слева от этого значения.

=ПОВТОР(“*”;24-ДЛСТР(ТЕКСТ(А1;“$# ##0.00”)))&ТЕКСТ(А1;“$# ##0.00”)

В отдельных случаях, когда возникает необходимость, вы можете использовать собственный числовой формат. Для того чтобы заполнить символами пустые позиции ячейки, достаточно просто включить в собственный формат звездочку (*). Например, используя следующее определение числового формата, можно дополнить число знаками тире:

$#,##0.00*-

Чтобы просто дополнить число звездочками, используйте в определении формата две звездочки, как показано ниже.

$#,##0.00**

Изменение регистра символов

Приложение Excel предлагает три весьма удобные функции, которые позволяют изменить регистр символов.

1. Функция ПРОПИСН преобразует все символы текста в верхний регистр.
2. Функция СТРОЧН преобразует весь текст в нижний регистр.
3. ПРОПНАЧ преобразует первый символ каждого слова в верхний регистр, а все остальные символы – в нижний.

Эти функции действуют очень просто. Например, следующая формула преобразует все символы текста в ячейке А1 в верхний регистр. Если ячейка А1 содержит текст MR. JOHN Q. PUBLIC, она вернет строку Mr. John Q. Public.

=ПРОПНАЧ(A1)

Следует отметить, что эти функции применяются только для символов, вошедших в алфавит. Все остальные символы они просто игнорируют и возвращают неизменными.

Функция ПРОПНАЧ не всегда приводит к нужному результату, поскольку она может неправильно трактовать некоторые слова. К примеру, фамилию McCartney она изменит на Mccartney.

Преобразование данных с помощью формул

Многие примеры этого раздела описывают методы использования функций для преобразования данных тем или иным способом. Например, можно применить функцию ПРОПИСН для преобразования текстовой строки в верхний регистр. Чаще всего исходные данные требуется заменить преобразованными данными. Для этого вставьте преобразованное значение поверх исходного текста.

1. Создайте формулы, преобразующие исходные данные.
2. Выделите ячейку с формулой.
3. Выберите команду ГлавнаяБуфер обменаКопировать.
4. Выделите исходную ячейку с формулой.
5. Выберите команду ГлавнаяБуфер обменаВставитьВставить значения.

После выполнения приведенных выше действий формула удаляется, а на ее место вставляются преобразованные данные.

Извлечение заданных символов из строки

Многие пользователи Excel достаточно часто сталкиваются с необходимостью извлечь из строки отдельные символы. Например, из списка служащих организации (имена и фамилии) требуется извлечь только фамилии всех сотрудников, чтобы в дальнейшем использовать часть текстовых данных каждой ячейки. Excel предоставляет несколько превосходных функций, позволяющих решить эту задачу.

• Функция ЛЕВСИМВ возвращает заданное количество символов с начала строки.
• Функция ПРАВСИМВ возвращает заданное количество символов с конца строки.
• Функция ПСТР возвращает заданное количество символов, начиная с любой позиции в пределах строки.

Формула, приведенная ниже, возвращает последние 10 символов содержимого ячейки А1. Если ячейка А1 содержит менее десяти символов, формула вернет текст ячейки в полном объеме.

=ПРАВСИМВ(А1;10)

В следующей формуле используется функция ПСТР. Она возвращает из ячейки А1 пять символов, начиная со второго. Другими словами, формула возвращает символы со второго по шестой.

=ПСТР(А1;2;5)

В следующем примере формула извлекает из текста, содержащегося в ячейке А1, только первый символ в верхнем регистре. Для этого используется функция ЛЕВСИМВ, которая позволяет извлечь первый символ и преобразовать его в верхний регистр. После этого набор символов присоединяется к другой строке, которая создается с помощью функции ПРАВСИМВ. В результате из заданного текста извлекается все, кроме первого символа, и извлеченные символы преобразуются в нижний регистр.

=ПРОПИСН(ЛЕВСИМВ(А1))&ПРАВСИМВ(СТРОЧН(А1);ДЛСТР(A1)-1)

Таким образом, если бы ячейка А1 содержала текст ПЯТЫЙ КВАРТАЛ, данная формула вернула бы текст Пятый квартал.

Замена одного текста другим

В некоторых ситуациях может возникнуть необходимость заменить определенную часть текста строки другим текстом. Например, некоторые импортируемые в приложение Excel данные содержат знаки звездочки, которые необходимо преобразовать в другие символы. Безусловно, для этого можно воспользоваться диалоговым окном Найти и заменить (команда ГлавнаяРедактированиеНайти и выделитьЗаменить). Если же вы хотите решить эту проблему с помощью формул, воспользуйтесь преимуществами любой из следующих двух функций.

1. Функция ПОДСТАВИТЬ заменяет в строке определенный текст или символ. Эту функцию лучше всего использовать, когда известен символ, который необходимо заменить, а не его расположение.
2. Функция ЗАМЕНИТЬ заменяет символ, расположенный в определенном месте в пределах строки. Данная функция используется при замене любого текста, если известно его местоположение. Содержимое самого текста или символа в данном случае не учитывается.

Ниже приведена формула, в которой используется функция ПОДСТАВИТЬ для замены значения года 2001 на 2002 в строке Бюджет 2001. Эта формула возвращает значение Бюджет 2002.

=ПОДСТАВИТЬ(“Бюджет 2001”;“2001”;“2002”)

Следующая формула использует функцию ПОДСТАВИТЬ для удаления из строки всех пробелов. Другими словами, она заменяет все пробелы пустой строкой и возвращает строку Белыйшоколадсизюмом.

=ПОДСТАВИТЬ(“Белый шоколад с изюмом”;“ ”;“”)

Приведенная далее формула использует функцию ЗАМЕНИТЬ для замены всего одного символа, расположенного в пятой позиции, ничего не вставляя вместо него. Иными словами, она просто удаляет шестой символ (дефис) и возвращает текст Часть544.

=ЗАМЕНИТЬ(“Часть-544”;6;1;“”)

Безусловно, можно вкладывать эти функции друг в друга, чтобы с помощью одной формулы выполнить множество замен. Обратите внимание, насколько может быть эффективной следующая формула, использующая несколько вложенных функций ПОДСТАВИТЬ. По большому счету, эта формула заменяет в ячейке А1 каждый из семи символов, следующих друг за другом: пробел, дефис, двоеточие, звездочку, символ подчеркивания, открывающую круглую скобку и закрывающую круглую скобку.

=ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(
ПОДСТАВИТЬ(ПОДСТАВИТЬ(А1;“ ”;“”);“-”;“”);“:”;“”);“*”;“”);“_”;“”);“(”;“”);“)”;“”)

Например, если ячейка А1 содержит строку Part-2A — Z(4М1)_А*, данная формула вернет Part2AZ4M1A.

Поиск в строке

Найти местонахождение определенного текста или символа в пределах одной строки в приложении Excel можно с помощью функций НАЙТИ и ПОИСК.

• Функция НАЙТИ обеспечивает поиск текста (подстроки) в пределах текстовой строки и возвращает исходную позицию этой подстроки. Можно определить позицию, с которой следует начать поиск текста. Эту функцию удобно использовать для сравнения текста с учетом регистра, но она не поддерживает сравнение групповых символов.
• Функция ПОИСК обеспечивает поиск определенной подстроки в пределах основной текстовой строки и возвращает значение исходной позиции подстроки. Для этой функции также можно определить место начала поиска. Данная функция используется для поиска нечувствительного к регистру текста или тогда, когда используются групповые символы.

В формуле, приведенной ниже, применена функция НАЙТИ, которая возвращает значение 7, т.е. номер позиции первого символа m, встречающегося в строке. Следует отметить, что эта формула учитывает регистр символов:

=НАЙТИ(“m”;“Big Mamma Thornton”;1)

Следующая формула использует функцию ПОИСК и возвращает значение 5 – номер позиции первого встреченного символа m. В этом случае регистр не учитывается.

=ПОИСК(“m”;“Big Mamma Thornton”;1)

В первом аргументе функции ПОИСК можно использовать следующие символы макроподстановки:

• вопросительный знак (?) соответствует любому одиночному символу;
• звездочка (*) соответствует любой последовательности символов.

Совет

Чтобы найти символы вопросительного знака или звездочки, введите в формуле перед этими символами тильду (~).

Следующая формула исследует текст в ячейке А1 и возвращает позицию первой последовательности из трех символов, содержащей в середине дефис. Иначе говоря, формула ищет любой символ, за которым следует знак дефиса и любой другой символ. Таким образом, если ячейка А1 содержит текст Part-А90, формула возвращает значение 4.

=ПОИСК(“?-?”;A1;1)

Поиск и замена в строке

Функция ПОИСК может использоваться совместно с функцией ЗАМЕНИТЬ, что позволяет заменить часть найденной текстовой строки другой строкой. В этом случае функция ПОИСК используется для того, чтобы найти начало расположения символов, с которым затем будет работать функция ЗАМЕНИТЬ.

Предположим, что ячейка А1 содержит текст Отчет о прибыли. Формула, приведенная ниже, отыскивает в этой строке слово прибыли и заменяет его на слово доходах.

=ЗАМЕНИТЬ(А1;ПОИСК(“прибыли”;А1);12;“доходах”)

Следующая формула использует функцию ПОДСТАВИТЬ для достижения того же эффекта, но более удобным способом:

=ПОДСТАВИТЬ(А1;“прибыли”;“доходах”)

В начало

Полезное

Добавить комментарий

Ваш e-mail не будет опубликован. Обязательные поля помечены *